At the end of last year, very quietly, the commentary to the Australian Concrete Structures Code (AS 3600) was published.  The commentary provides a wide range of explanatory and background information to the requirements in the main code, including some aspects that are neither obvious nor widely known.

Download Reinforced Concrete Design Functions for free open source Excel functions, including the shrinkage calculation described below.

An example is the calculation of design shrinkage strain from the standard 56 day test value.  The total design shrinkage for any concrete mix consists of two components:

• The chemical (or autogenous) shrinkage, which is a property of the mix, and is specified in the code dependent on the concrete compressive strength.
• The drying shrinkage, which is affected by the mix and also the environment and concrete section dimensions.

To find the design drying shrinkage the basic drying shrinkage is factored depending on environmental conditions, section thickness, and time since completion of curing.  Standard values are provided for the basic drying shrinkage (depending on location), but this value may also be derived from test data, using the standard 56 day shrinkage test to AS 1012.13.  Calculation of the basic drying shrinkage from the test value requires the following steps:

1.  Find the Test Drying Shrinkage by deducting the part of the chemical shrinkage that occurred between completion of wet curing (7 days) and completion of the test (56 days).
2. Find the code K1 and K4 factors.  For the standard test K1 = 1.446 and K4 = 0.7.
3. The Basic Drying Shrinkage is then given by:
   (Test drying shrinkage) / (K1 * K4 * (1 – 0.008 * fc))

VBA code performing this calculation is shown below:

Function BDS(fc As Double, Testshrink As Double, Optional CureDays As Double = 7, Optional TestDays As Double = 56, _
            Optional HypeThick As Double = 37.5, Optional K_4 As Double = 0.7, Optional Out1 As Long) As Variant
    Dim Alpha As Double, ResA(1 To 6, 1 To 1) As Double, TestDShrink As Double
    Dim AFShrink As Double, AShrinkS As Double, AShrinkE As Double, BDShrink As Double, Alpha1 As Double, K_1 As Double, DShrink As Double, TShrink As Double
    Dim BetaRH As Double, Alphads1 As Double, Alphads2 As Double, Kh As Double, Betads As Double, TotalDays As Double

    AFShrink = (0.06 * fc - 1) * 50
    AShrinkS = AFShrink * (1 - Exp(-CureDays / 10))
    AShrinkE = AFShrink * (1 - Exp(-TestDays / 10))
    TestDShrink = Testshrink - (AShrinkE - AShrinkS)
    Alpha1 = 0.8 + 1.2 * Exp(-HypeThick * 0.005)
    K_1 = Alpha1 * TestDays ^ 0.8 / (TestDays ^ 0.8 + 0.15 * HypeThick)
    BDShrink = TestDShrink / (K_1 * K_4 * (1 - 0.008 * fc))

    ResA(1, 1) = BDShrink
    ResA(2, 1) = AShrinkS
    ResA(3, 1) = AShrinkE
    ResA(4, 1) = TestDShrink
    ResA(5, 1) = Alpha1
    ResA(6, 1) = K_1

    If Out1 = 0 Then
        BDS = ResA
    Else
        BDS = ResA(Out1, 1)
    End If

End Function

An example of the use of the function is shown in the screen shot below. Note that:

•  For the standard 56 day test the only input required is the concrete grade and the test shrinkage value (in microstrain).
• The function returns a column array of six values (as shown).  To display all six values enter as an array function.
• The first value returned is the Basic Drying Shrinkage.  This must be factored as detailed in the code to find the design drying shrinkage, then add the chemical (autogenous) shrinkage to find the final Design Shrinkage.
• The spreadsheet Shrink() function will return the Design Shrinkage after any given period, for specified Basic Drying Shrinkage, concrete grade, hypothetical thickness, and K4 values.